Can we get a new BGInfo for Windows 7?

@echo off
setlocal enableextensions 
echo - %* | findstr /i /c:"/?" > NUL: && goto :help
echo - %* | findstr /i /c:"/v" > NUL: && goto :version
echo - %* | findstr /i /c:"/d" > NUL: && echo on
if exist "%~dp0\bin" path "%~dp0\bin";%path%
mkdir "%~dp0\output" 2> NUL:
ver | findstr /c:"Version 6.1" > NUL: || goto :pre7
:pc
::
:: The following is logic specific to Providence College. Its purpose 
:: is to switch between BGINFO templates based on a PCINFO value
:: (read from a script PCVAR).  You can safely delete the section 
:: within the :pc and :/pc labels.
::
call pcvar pcinfo || goto :/pc
echo %computername% | findstr /i /b "ZZ" > NUL: && set "_pcinfo=TEMPLATE"
set "_bgifile=%~dp0\bginfo-%_pcinfo%.bgi"
:/pc
:win7
if not exist "%_bgifile%" set "_bgifile=%~dp0\bginfo-7.bgi"
icacls "%~dp0\output" /grant everyone:(OI)(CI)(F) /t
bginfo /nolicprompt "%_bgifile%" /timer:0
::
:: Note: as of this writing, LFC will fail when a path is surrounded 
:: by quotes and ends in a backslash.
::
lfc "%~dp0\output" "%~dp0\output" /b24 /f10 /q2 /noui 
for %%i in ("%~dp0\output\backgroundDefault.jpg") do if %%~zi GEQ 256000 lfc "%~dp0\output" "%~dp0\output" /b2 /f10 /q2 /noui
mkdir "%windir%\system32\oobe\info\backgrounds" 2> NUL:
icacls "%windir%\system32\oobe\info" /grant everyone:(OI)(CI)(F) /t
copy /v /y "%~dp0\output\backgroundDefault.jpg" "%windir%\system32\oobe\info\backgrounds\"
reg add HKLM\Software\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Background /v OEMBackground /t REG_DWORD /d 1 /f
%SystemRoot%\System32\rundll32.exe user32.dll, UpdatePerUserSystemParameters
@goto :eof
:pre7
ver | findstr /c:"Version 6.0" && goto :vista
cacls "%~dp0\output" /t /e /g everyone:F
bginfo /nolicprompt "%~dp0\bginfo-xp.bgi" /timer:0
reg add "HKU\.DEFAULT\Control Panel\Desktop" /v Wallpaper /t REG_SZ /d "%~dp0\output\backgroundDefault.bmp" /f
%SystemRoot%\System32\rundll32.exe user32.dll, UpdatePerUserSystemParameters
@goto :eof
:vista
@echo off
echo PCINFO is not supported on Windows Vista due to the way the login screen is 
echo encoded in a DLL.  For more information, see:
echo.
echo http://forum.sysinternals.com/topic14184.html
echo.
@goto :eof
:help
@echo off
echo Creates picture with system info on the login screen.
echo.
echo PCINFO [/?] [/V] [/D]
echo.
echo   /V      Version history
echo   /D      Debugging
echo.
echo PCINFO uses the Sysinternals utility BGINFO (http://www.sysinternals.com) 
echo to create a bitmap with system information.  This screen can be used 
echo directly by Windows NT, 2000, XP, or 2003, but needs to be converted 
echo for use by Windows 7 or Windows Server 2K8.
echo.
echo To convert the image it uses a LFC, a free command-line file converter 
echo from LEAD Tools (http://www.leadtools.com).
echo.
echo Both BGINFO and LFC are stored in a .\bin subdirectory from the PCINFO 
echo script.  The bitmap generated by BGINFO is stored in an .\output 
echo subdirectory (which is created if it does not already exist).
echo.
echo If the path for the PCINFO tool needs to change, open the BGINFO.BGI 
echo file in the same directory as the script and change a) the output 
echo directory for the bitmap (under Bitmap:Location), and b) the _pcinfo 
echo custom field location (under Fields:Custom; this is a VBscript file 
echo in the same directory which parses NIC information).
echo.
@goto :eof
:version
@echo off
echo.
echo Written by Adam Hauerwas, hauerwas@providence.edu
echo.
echo See http://forum.sysinternals.com/topic20426.html for description of 
echo approach and operation.  Latest version can be downloaded from 
echo http://dl.dropbox.com/u/13326617/pcinfo.zip
echo.
echo 03/19/2010 - Version 1.0 released
echo 12/29/2010 - Version 1.5 released
echo.
@goto :eof

Const iPad = 20
Set WSHShell = CreateObject("WScript.Shell")
'Subroutines
'Output tabular data
Sub Output (strLeft, strRight)
 Do While InStr(strRight, "  ") > 0
  strRight = Replace(strRight, "  ", " ")
 Loop
 strOutput = Left(strLeft & String(iPad," "),iPad) & vbTab & strRight
 Echo strOutput
End Sub
'Output host name, specs, deployment date and image tag
'Get Install Date using WMI
'Taken from http://msdn.microsoft.com/en-us/library/aa394596(v=vs.85).aspx
strComputer = "."
strImage = WSHShell.Environment.item("_image") 
if strImage <> "" Then strImage = ", Image " & strImage
Set objWMIService = GetObject("winmgmts:" _
 & "{impersonationLevel=impersonate}!\\" _
 & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery _
 ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
 Output Field("Host Name"), _
 (Field("CPU") & ", " & Field("Memory")) _
 & " (Deployed " & Left (objOperatingSystem.InstallDate, 8) _
 & strImage & ")"
Next
'Parse the MAC address and NIC arrays to matched pairs
'(and ignore Bluetooth or Juniper adapters)
'
arrMAC = Split ( Field("MAC Address"), CHR(11) )
arrNIC = Split ( Field("Network Card"), CHR(11) )
For iLoop = 0 to UBound(arrMAC)
 MAC = Replace( arrMAC(iLoop), CHR(11), "", 1, -1, 1 )
 NIC = Replace( arrNIC(iLoop), CHR(11), "", 1, -1, 1 )
 If InStr(NIC, "Bluetooth") + InStr(NIC, "Juniper") = 0 Then Output MAC, NIC
Next
Echo ""
Echo Field("Snapshot Time")